1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
|
const std = @import("std");
const posix = std.posix;
const io = std.Io;
const sdl3 = @import("sdl3");
const mixer = sdl3.mixer;
/// file descriptor da stdin para sistemas linux
const STDIN_FD: posix.fd_t = 0;
/// para mais informações, ler `termios(3)`
/// número mínimo de caracteres a serem lidos no modo `raw`
/// timeout para ler a stdin, em decisegundos
const VMIN = @intFromEnum(std.os.linux.V.MIN);
const VTIME = @intFromEnum(std.os.linux.V.TIME);
/// ANSI escape codes
/// https://en.wikipedia.org/wiki/ANSI_escape_code#Control_Sequence_Introducer_commands
const CNL = "\x1B[1E";
const CPL = "\x1B[1F";
const REVERSE = "\x1B[7m";
const NOT_REVERSE = "\x1B[27m";
const song = "assets/protection.mp3";
pub fn main(
init: std.process.Init,
) !void {
defer sdl3.shutdown();
try sdl3.init(.{ .audio = true });
defer sdl3.quit(.{ .audio = true });
try mixer.init();
defer mixer.quit();
// Open a mixer on the default playback device, letting SDL mixer pick the format.
const mixer_device = try mixer.Mixer.initDevice(sdl3.audio.Device.default_playback, null);
defer mixer_device.deinit();
const wav = try mixer.Audio.init(mixer_device, song, true);
defer wav.deinit();
const metadata = try wav.getProperties();
const titulo = metadata.title orelse "";
const artista = metadata.artist orelse "";
const album = metadata.album orelse "";
const duracao_frames = metadata.duration_frames orelse 0;
const duracao_ms = try wav.framesToMs(duracao_frames);
const minutos, const segundos = msToElapsedTime(duracao_ms);
const track = try mixer.Track.init(mixer_device);
defer track.deinit();
try track.setAudio(wav);
try track.play(.{});
// estado original do terminal
const termios_ro = try posix.tcgetattr(STDIN_FD);
// ativa modo `raw` do terminal
var termios_rw = termios_ro;
termios_rw.oflag.OPOST = false;
termios_rw.iflag.IGNBRK = false;
termios_rw.iflag.BRKINT = false;
termios_rw.iflag.PARMRK = false;
termios_rw.iflag.ISTRIP = false;
termios_rw.iflag.INLCR = false;
termios_rw.iflag.ICRNL = false;
termios_rw.iflag.IGNCR = false;
termios_rw.iflag.IXON = false;
termios_rw.oflag.OPOST = false;
termios_rw.lflag.ECHO = false;
termios_rw.lflag.ECHONL = false;
termios_rw.lflag.ICANON = false;
termios_rw.lflag.ISIG = false;
termios_rw.lflag.IEXTEN = false;
termios_rw.cflag.CSIZE = .CS8;
termios_rw.cflag.PARENB = false;
termios_rw.cc[VMIN] = 0;
termios_rw.cc[VTIME] = 1;
try posix.tcsetattr(STDIN_FD, .FLUSH, termios_rw);
var stdout = io.File.stdout();
var stdin = io.File.stdin();
var w_buffer: [256]u8 = undefined;
var stdout_writer = stdout.writer(init.io, &w_buffer);
const writer_interface = &stdout_writer.interface;
var segundo_atual: i64 = 0;
var duracao_loop: i64 = 0;
var quit_app = false;
while (!quit_app) {
const inicio_loop = io.Clock.now(.real, init.io);
const tempo_decorrido_ms = @as(usize, @intCast(segundo_atual));
const min_decorrido, const seg_decorrido = msToElapsedTime(tempo_decorrido_ms);
try writer_interface.print("\r{d}:{d:02} / {d}:{d}", .{ min_decorrido, seg_decorrido, minutos, segundos });
try writer_interface.print(CNL, .{});
try writer_interface.print("\rVolume: {d}\r", .{ @round(track.getGain() * 100) });
try writer_interface.print(CNL, .{});
try writer_interface.print("\r{s} | {s} | {s}", .{ titulo, artista, album });
try writer_interface.print(CNL, .{});
try writer_interface.print("\r{s}<Espaço>{s}: pausar/reproduzir | =/+: aumentar volume | -: diminuir volume | q: sair", .{ REVERSE, NOT_REVERSE });
try writer_interface.print(CPL, .{});
try writer_interface.print(CPL, .{});
try writer_interface.print(CPL, .{});
try writer_interface.print(CPL, .{});
try writer_interface.flush();
// lê comandos
var r_buffer: [64]u8 = undefined;
var stdin_reader = stdin.reader(init.io, &r_buffer);
const reader_interface = &stdin_reader.interface;
// lê apenas um caractere da stdin
const char = reader_interface.peek(1) catch "";
if (std.mem.eql(u8, char, " ")) {
if (track.isPaused()) {
try track.resumeTrack();
} else {
try track.pause();
}
} else if (std.mem.eql(u8, char, "q")) {
quit_app = true;
} else if (std.mem.eql(u8, char, "=") or std.mem.eql(u8, char, "+")) {
const cur_gain = track.getGain();
try track.setGain(cur_gain + 0.1);
} else if (std.mem.eql(u8, char, "-")) {
const cur_gain = track.getGain();
try track.setGain(cur_gain - 0.1);
}
const fim_loop = io.Clock.now(.real, init.io);
duracao_loop = inicio_loop.durationTo(fim_loop).toMilliseconds();
if (!track.isPaused()) {
segundo_atual += duracao_loop;
}
}
// restaura terminal pro estado original ao final
try posix.tcsetattr(0, .FLUSH, termios_ro);
try track.stop(0);
try writer_interface.print("\n\n\n", .{});
try writer_interface.flush();
}
/// Transforma milissegundos em duração padrão no formato MM:ss
fn msToElapsedTime(ms: usize) [2]usize {
const seg_raw = ms / 1000;
const min = seg_raw / 60;
const seg = seg_raw % 60;
return .{ min, seg };
}
|