aboutsummaryrefslogtreecommitdiff
path: root/src/main.zig
blob: 363fea3ccd0a0269d92d141afa23a1a26f3276bc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
const std = @import("std");
const posix = std.posix;

const sdl3 = @import("sdl3");
const mixer = sdl3.mixer;

/// file descriptor da stdin para sistemas linux
const STDIN_FD: posix.fd_t = 0;

/// para mais informações, ler `termios(3)`
/// número mínimo de caracteres a serem lidos no modo `raw`
/// timeout para ler a stdin, em decisegundos
const VMIN = @intFromEnum(std.os.linux.V.MIN);
const VTIME = @intFromEnum(std.os.linux.V.TIME);

/// ANSI escape codes
/// https://en.wikipedia.org/wiki/ANSI_escape_code#Control_Sequence_Introducer_commands
const CNL = "\x1B[1E";
const CPL = "\x1B[1F";
const REVERSE = "\x1B[7m";
const NOT_REVERSE = "\x1B[27m";

/// interface
const BARRA = "█";
const PONTO = "•";

pub fn main(
    init: std.process.Init,
) !void {
    var args = try init.minimal.args.iterateAllocator(init.gpa);
    defer args.deinit();

    var song: [:0]const u8 = "assets/protection.mp3";
    _ = args.skip(); //  primeiro argumento é o nome do arquivo
    // TODO: aceitar múltiplos arquivos e colocá-los em uma FILA!!
    while (args.next()) |arg| {
        const path = std.fs.path.parsePath(arg);
        var dir: std.Io.Dir = std.Io.Dir.cwd();
        if (path.kind == .absolute) {
            std.Io.Dir.accessAbsolute(init.io, path.root, .{}) catch |err| switch (err) {
                error.FileNotFound => {
                    std.debug.print("[ERROR] Directory {s} not found.\n", .{path.root});
                    return err;
                },
                else => {
                    std.debug.print("Unknown: {t}\n", .{err});
                    return err;
                },
            };
        } else {
            dir.access(init.io, ".", .{}) catch |err| switch (err) {
                error.FileNotFound => {
                    std.debug.print("[ERROR] File {s} not found.\n", .{arg});
                    return err;
                },
                else => {
                    std.debug.print("Unknown: {t}.\n", .{err});
                    return err;
                },
            };
        }

        song = arg;
    }

    defer sdl3.shutdown();

    try sdl3.init(.{ .audio = true });
    defer sdl3.quit(.{ .audio = true });

    try mixer.init();
    defer mixer.quit();

    // Open a mixer on the default playback device, letting SDL mixer pick the format.
    const mixer_device = try mixer.Mixer.initDevice(sdl3.audio.Device.default_playback, null);
    defer mixer_device.deinit();

    const audio = mixer.Audio.init(mixer_device, song, true) catch |err| {
        std.debug.print("[ERROR] file {s} is not a valid audio file.\n", .{song});
        return err;
    };
    defer audio.deinit();

    const metadata = try audio.getProperties();
    const titulo = metadata.title orelse "";
    const artista = metadata.artist orelse "";
    const album = metadata.album orelse "";

    const duracao_frames: usize = metadata.duration_frames orelse 0;
    const duracao_ms = try audio.framesToMs(duracao_frames);
    const minutos, const segundos = msToElapsedTime(duracao_ms);

    const track = try mixer.Track.init(mixer_device);
    defer track.deinit();
    try track.setAudio(audio);

    try track.play(.{});
    // só por enquanto pq toda vez estoura meu tímpano
    try track.setGain(0.2);

    // estado original do terminal
    const termios_ro = try posix.tcgetattr(STDIN_FD);

    // ativa modo `raw` do terminal
    var termios_rw = termios_ro;

    termios_rw.oflag.OPOST = false;

    termios_rw.iflag.IGNBRK = false;
    termios_rw.iflag.BRKINT = false;
    termios_rw.iflag.PARMRK = false;
    termios_rw.iflag.ISTRIP = false;
    termios_rw.iflag.INLCR = false;
    termios_rw.iflag.ICRNL = false;
    termios_rw.iflag.IGNCR = false;
    termios_rw.iflag.IXON = false;

    termios_rw.oflag.OPOST = false;

    termios_rw.lflag.ECHO = false;
    termios_rw.lflag.ECHONL = false;
    termios_rw.lflag.ICANON = false;
    termios_rw.lflag.ISIG = false;
    termios_rw.lflag.IEXTEN = false;

    termios_rw.cflag.CSIZE = .CS8;
    termios_rw.cflag.PARENB = false;

    termios_rw.cc[VMIN] = 0;
    termios_rw.cc[VTIME] = 1;

    try posix.tcsetattr(STDIN_FD, .FLUSH, termios_rw);

    var stdout = std.Io.File.stdout();
    var stdin = std.Io.File.stdin();

    var w_buffer: [256]u8 = undefined;
    var stdout_writer = stdout.writer(init.io, &w_buffer);
    const writer_interface = &stdout_writer.interface;

    const segundos_por_parcela: usize = duracao_ms / 100;

    var ms_atual: usize = 0;
    var duracao_loop: usize = 0;

    var quit_app = false;
    while (!quit_app) {
        const inicio_loop = std.Io.Clock.now(.real, init.io);

        // lê comandos
        var r_buffer: [64]u8 = undefined;
        var stdin_reader = stdin.reader(init.io, &r_buffer);
        const reader_interface = &stdin_reader.interface;
        // https://github.com/rockorager/libvaxis/blob/d4c3b3666e0c090e2b5092ca09893c6db15e0b79/src/widgets/terminal/Parser.zig
        const byte = reader_interface.takeByte() catch 0;
        switch (byte) {
            0x1B => {
                var next = try reader_interface.takeByte();
                if (next != '[') {
                    continue;
                }
                next = try reader_interface.takeByte();
                switch (next) {
                    // https://en.wikipedia.org/wiki/ANSI_escape_code#Terminal_input_sequences
                    // seta pra esquerda
                    'D' => {
                        const cur_frame = try track.getPlaybackPosition();
                        const framesFromMs = try track.msToFrames(5000);
                        if (cur_frame <= framesFromMs) {
                            try track.setPlaybackPosition(0);
                            ms_atual = 0;
                            continue;
                        }

                        const frames_decorridos = cur_frame - framesFromMs;
                        if (track.getRemaining()) |frames_restantes| {
                            if (frames_restantes == 0) {
                                try track.play(.{ .start_frame = (duracao_frames - framesFromMs) });
                            } else if (frames_restantes > 0) {
                                try track.setPlaybackPosition(frames_decorridos);
                            } else {
                                return error.Unknown;
                            }
                        }
                        ms_atual = if (ms_atual <= 5000) 0 else ms_atual - 5000;
                    },
                    // seta pra direita
                    'C' => {
                        const cur_frame = try track.getPlaybackPosition();
                        const framesFromMs = try track.msToFrames(5000);
                        if ((duracao_frames - cur_frame) <= framesFromMs) {
                            try track.setPlaybackPosition(duracao_frames);
                            continue;
                        }

                        const frames_decorridos = cur_frame + framesFromMs;
                        try track.setPlaybackPosition(frames_decorridos);
                        ms_atual = if ((duracao_ms - ms_atual) <= 5000) duracao_ms else ms_atual + 5000;
                    },
                    else => {
                        continue;
                    },
                }
            },
            ' ' => {
                if (track.isPaused()) {
                    try track.resumeTrack();
                } else {
                    try track.pause();
                }
            },
            'q' => quit_app = true,
            '=', '+' => {
                const cur_gain = track.getGain();
                try track.setGain(cur_gain + 0.1);
            },
            '-' => {
                const cur_gain = track.getGain();
                try track.setGain(cur_gain - 0.1);
            },
            else => {},
        }

        const min_decorrido, const seg_decorrido = msToElapsedTime(ms_atual);

        // BARRA DE PROGRESSO:
        // dividir a duração da música em 100 parcelas de x segundos
        // para cada x segundos decorridos, renderizar x * █
        // depois disso, renderizar (100 - x) * • para os segundos não decorridos
        const num_parcelas = ms_atual / segundos_por_parcela;
        _ = try writer_interface.writeAll("\r");
        _ = try writer_interface.splatBytesAll(BARRA, num_parcelas);
        _ = try writer_interface.splatBytesAll(PONTO, (100 - num_parcelas));
        try writer_interface.flush();
        try writer_interface.print(CNL, .{});

        try writer_interface.print("\r{d}:{d:02} / {d}:{d:02}", .{
            min_decorrido,
            seg_decorrido,
            minutos,
            segundos,
        });
        try writer_interface.print(CNL, .{});
        try writer_interface.print("\rVolume: {d}\r", .{@round(track.getGain() * 100)});
        try writer_interface.print(CNL, .{});
        try writer_interface.print("\r{s} | {s} | {s}", .{ titulo, artista, album });
        try writer_interface.print(CNL, .{});
        try writer_interface.print("\r{s}<Espaço>{s}: pausar/reproduzir | =/+: aumentar volume | -: diminuir volume | q: sair", .{
            REVERSE,
            NOT_REVERSE,
        });
        try writer_interface.print(CPL, .{});
        try writer_interface.print(CPL, .{});
        try writer_interface.print(CPL, .{});
        try writer_interface.print(CPL, .{});
        try writer_interface.flush();

        const fim_loop = std.Io.Clock.now(.real, init.io);
        duracao_loop = @as(usize, @intCast(inicio_loop.durationTo(fim_loop).toMilliseconds()));
        if (!track.isPaused()) {
            ms_atual += duracao_loop;
        }
    }

    // restaura terminal pro estado original ao final
    try posix.tcsetattr(0, .FLUSH, termios_ro);

    try track.stop(0);
    try writer_interface.print("\n\n\n", .{});
    try writer_interface.flush();
}

/// Transforma milissegundos em duração padrão no formato MM:ss
fn msToElapsedTime(ms: usize) [2]usize {
    if (ms == 0) {
        return .{ 0, 0 };
    }

    const seg_raw = ms / 1000;
    const min = seg_raw / 60;
    const seg = seg_raw % 60;

    return .{ min, seg };
}