aboutsummaryrefslogtreecommitdiff
path: root/fish/functions/n.fish
blob: 407361ec4c403a67e6f440623102dcdb81ae4fda (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
function n --wraps=nnn --description 'support nnn quit and change directory'
    # Block nesting of nnn in subshells
    if test -n "$NNNLVL" -a "$NNNLVL" -ge 1
        echo "nnn is already running"
        return
    end

    # The behaviour is set to cd on quit (nnn checks if NNN_TMPFILE is set)
    # If NNN_TMPFILE is set to a custom path, it must be exported for nnn to
    # see. To cd on quit only on ^G, remove the "-x" from both lines below,
    # without changing the paths.
    if test -n "$XDG_CONFIG_HOME"
        set -x NNN_TMPFILE "$XDG_CONFIG_HOME/nnn/.lastd"
    else
        set -x NNN_TMPFILE "$HOME/.config/nnn/.lastd"
    end

    # Unmask ^Q (, ^V etc.) (if required, see `stty -a`) to Quit nnn
    # stty start undef
    # stty stop undef
    # stty lwrap undef
    # stty lnext undef

    # The command function allows one to alias this function to `nnn` without
    # making an infinitely recursive alias
    command nnn $argv

    if test -e "$NNN_TMPFILE"
        # nnn writes POSIX shell syntax, whose quoting differs from fish.
        # NUL separation preserves paths containing (or ending in) newlines.
        set -l lastdir (command sh -c '. "$1" && printf "%s\000" "$PWD"' sh "$NNN_TMPFILE" | string split0)
        if set -q lastdir[1]
            cd -- "$lastdir"
        end
        rm -- "$NNN_TMPFILE" >/dev/null
    end
end